Autonomous Databaseでの自動パーティション化の管理

推奨事項の有効化および実装

EXEC DBMS_AUTO_PARTITION.CONFIGURE('AUTO_PARTITION_MODE','IMPLEMENT');

推奨事項を有効化しますが、それらの推奨事項は実装しません。

EXEC DBMS_AUTO_PARTITION.CONFIGURE('AUTO_PARTITION_MODE','REPORT ONLY');

新しい推奨事項の無効化およびこれらの新しい推奨事項の実装

EXEC DBMS_AUTO_PARTITION.CONFIGURE('AUTO_PARTITION_MODE','OFF');

自動パーティション化のためのスキーマおよび表の管理

• 包含リストおよび除外リストが空の場合、除外リストにHRスキーマおよびSH.SALES表を追加して、それらのオブジェクトのみが自動パーティション化分析されないようにします。

  BEGIN
      DBMS_AUTO_PARTITION.CONFIGURE(
           PARAMETER_NAME  => 'AUTO_PARTITION_SCHEMA', 
           PARAMETER_VALUE => 'HR',
           ALLOW           => FALSE);
  
      DBMS_AUTO_PARTITION.CONFIGURE(
           PARAMETER_NAME  => 'AUTO_PARTITION_TABLE', 
           PARAMETER_VALUE => 'SH.SALES',
           ALLOW           => FALSE);
  END;
  /

• 前述の例の実行後、次を使用して除外リストからHRスキーマを削除します。

  BEGIN
      DBMS_AUTO_PARTITION.CONFIGURE(
           PARAMETER_NAME  => 'AUTO_PARTITION_SCHEMA', 
           PARAMETER_VALUE => 'HR',
           ALLOW           => NULL);
  END;
  /

• 次のコマンドを使用して、除外リストからすべてのスキーマを削除します。

  BEGIN
      DBMS_AUTO_PARTITION.CONFIGURE(
           PARAMETER_NAME  => 'AUTO_PARTITION_SCHEMA', 
           PARAMETER_VALUE => NULL,
           ALLOW           => TRUE);
  END;
  /

• 包含リストと除外リストが空の場合、次の例では、包含リストにHRスキーマを追加します。包含リストが空でなくなると、包含リスト内のスキーマのみが考慮されます。

  この例では、自動パーティション化の候補はHRスキーマのみです。

  BEGIN
      DBMS_AUTO_PARTITION.CONFIGURE(
           PARAMETER_NAME  => 'AUTO_PARTITION_SCHEMA', 
           PARAMETER_VALUE => 'HR',
           ALLOW           => TRUE);
  END;
  /

自動パーティション化レポート保持期間の管理

自動パーティション化レポートの保存期間を365日に設定します。

BEGIN
    DBMS_AUTO_PARTITION.CONFIGURE(
         PARAMETER_NAME  => 'AUTO_PARTITION_REPORT_RETENTION', 
         PARAMETER_VALUE => '365');
END;
/

特定の期間の自動パーティション化操作のレポートをプレーン・テキスト形式で生成します。

この例では、過去24時間の自動パーティション化操作に関する一般的な情報を含むレポートを生成します。デフォルトでは、このレポートはプレーン・テキスト形式で生成されます。

DECLARE
  Report clob := NULL
BEGIN
    Report := DBMS_AUTO_PARTITION.REPORT_ACTIVITY();
END;
/

MAY 2021の自動パーティション化操作のレポートをHTML形式で生成します。

この例では、2021年5月の自動パーティション化操作に関する基本情報を含むレポートを生成します。レポートはHTML形式で生成され、自動パーティション化操作のサマリーのみを含んでいます。

DECLARE
  Report clob := NULL
BEGIN
    Report := DBMS_AUTO_PARTITION.REPORT_ACTIVITY(
                       ACTIVITY_START => TO_TIMESTAMP('2021-05-01', 'YYYY-MM-DD'),
                       ACTIVITY_END   => TO_TIMESTAMP('2021-06-01', 'YYYY-MM-DD'),
                       TYPE           => 'HTML',
                       SECTION        => 'SUMMARY',
                       LEVEL          => 'BASIC' );
END;
/

最後の自動パーティション化操作のプレーン・テキスト形式でレポートを生成します。

この例では、最後の自動パーティション化操作に関する一般的な情報を含むレポートを生成します。デフォルトでは、このレポートはプレーン・テキスト形式で生成されます。

DECLARE
  Report clob := NULL
BEGIN
    Report := DBMS_AUTO_PARTITION.REPORT_LAST_ACTIVITY();
END;
/

詳細は、REPORT_ACTIVITYファンクションを参照してください。

詳細は、REPORT_LAST_ACTIVITYファンクションを参照してください。

単一の表の推奨事項を生成し、推奨事項を手動で適用します。

1. AUTO_PARTITION_MODEパラメータをREPORT ONLYに設定して、自動パーティション化の推奨事項を作成して検証できるようにします。推奨は表に適用されません。

   BEGIN
       DBMS_AUTO_PARTITION.CONFIGURE(
           PARAMETER_NAME  => 'AUTO_PARTITION_MODE', 
           PARAMETER_VALUE => 'REPORT ONLY');
   END;
   /

2. TPCH.LINEITEM表が自動パーティション化の候補であることを確認します。単一表を選択的にターゲット指定する場合は、このステップはオプションであり、推奨されます。

   SELECT DBMS_AUTO_PARTITION.VALIDATE_CANDIDATE_TABLE(
              TABLE_OWNER => 'TPCH',
              TABLE_NAME  => 'LINEITEM')
   FROM DUAL;

   表が有効な候補である場合、推奨分析に対して自動パーティション化を起動すると、VALIDとして戻されます。それ以外の場合は、違反基準が表示されます。

   適格な候補表の基準のリストは、VALIDATE_CANDIDATE_TABLEファンクションを参照してください。

3. DBMS_AUTO_PARTITION APIを起動して、TPCH.LINEITEM表の推奨事項を生成します。

   -- DEFINE SQLPLUS BIND VARIABLE FOR RECOMMENDATION ID
   VARIABLE RECOMMENDATION_ID VARCHAR2(32);
   BEGIN
     :RECOMMENDATION_ID := DBMS_AUTO_PARTITION.RECOMMEND_PARTITION_METHOD(
                                TABLE_OWNER => 'TPCH',
                                TABLE_NAME  => 'LINEITEM');
   END;
   /

   DBMS_AUTO_PARTITION.RECOMMEND_PARTITION_METHODで実行する推奨事項の分析および検証は、リソース集中型の長時間実行操作であり、かなりの時間がかかる場合があります。このステップは、プライマリ本番システムではないデータベースで実行する必要があります。Oracleでは、HIGHサービスを選択して検証操作に十分なリソースを提供することをお薦めします。

4. 推奨事項を確認します。ビューDBA_AUTO_PARTITION_RECOMMENDATIONSには、推奨事項に関する情報が含まれます。この例では、推奨されるパーティション・キーおよびパーティション・メソッドを確認します。

   SELECT PARTITION_METHOD, PARTITION_KEY
     FROM DBA_AUTO_PARTITION_RECOMMENDATIONS
     WHERE RECOMMENDATION_ID = :RECOMMENDATION_ID;
   

   また、同じビューを問い合せて、推奨に従って表がパーティション化された後、ワークロードに対して生成されたパフォーマンス分析レポートを取得します。

   SELECT REPORT
       FROM DBA_AUTO_PARTITION_RECOMMENDATIONS
       WHERE RECOMMENDATION_ID = :RECOMMENDATION_ID;
   

5. 推奨事項の手動検証後に、推奨事項を適用します。推奨事項分析が実行されたデータベースで推奨事項を適用する場合は、APPLY_RECOMMENDATIONプロシージャを実行して推奨事項を適用します。

   BEGIN
       DBMS_AUTO_PARTITION.APPLY_RECOMMENDATION(
            RECOMMENDATION_ID => :RECOMMENDATION_ID);
   END;
   /

   本番環境などの別のデータベースに推奨事項を適用する場合は、変更DDLを抽出します。次に、ターゲット・データベースで抽出された変更DDLを実行します。変更DDLを抽出する問合せは次のとおりです。

   SELECT MODIFY_TABLE_DDL
       FROM DBA_AUTO_PARTITION_RECOMMENDATIONS
       WHERE RECOMMENDATION_ID = :RECOMMENDATION_ID;
   

   変更DDLの出力例:

   BEGIN
       -- DBMS_AUTO_PARTITION RECOMMENDATION_ID C3F7A59E085C2F25E05333885A0A55EA
       --   FOR TABLE "TPCH"."LINEITEM"
       --   GENERATED AT 06/04/2021 20:52:29
       DBMS_AUTO_PARTITION.BEGIN_APPLY(EXPECTED_NUMBER_OF_PARTITIONS => 10);
   
       EXECUTE IMMEDIATE
       'ALTER TABLE "TPCH"."LINEITEM"
       MODIFY PARTITION BYLIST(SYS_OP_INTERVAL_HIGH_BOUND
           ("L_SHIPDATE", INTERVAL ''10'' MONTH, TIMESTAMP ''1992-01-01 00:00:00''))
       AUTOMATIC /* SCORE=23533.11;  */
       (PARTITION P_NULL VALUES(NULL))
       AUTO ONLINE PARALLEL';
   
       DBMS_AUTO_PARTITION.END_APPLY;
   EXCEPTION WHEN OTHERS THEN
       DBMS_AUTO_PARTITION.END_APPLY;
       RAISE;
   END;
   

6. 表が自動的にパーティション化されていることを確認し、カタログ・ビューを問い合せます。

   SELECT T.AUTO, T.PARTITIONING_TYPE, C.COLUMN_NAME
       FROM DBA_PART_TABLES T, DBA_PART_KEY_COLUMNS C
       WHERE T.OWNER = 'TPCH' AND T.TABLE_NAME = 'LINEITEM'
           AND T.OWNER = C.OWNER AND T.TABLE_NAME = C.NAME;
   

   この問合せを使用して、指定された表に自動パーティション化がいつ適用されたかを識別します。

   SELECT APPLY_TIMESTAMP_START, APPLY_TIMESTAMP_END
       FROM DBA_AUTO_PARTITION_RECOMMENDATIONS
       WHERE TABLE_OWNER = 'TPCH' AND TABLE_NAME = 'LINEITEM';
   

詳細は、CONFIGUREプロシージャを参照してください。

詳細は、VALIDATE_CANDIDATE_TABLEファンクションを参照してください。

詳細は、RECOMMEND_PARTITION_METHODファンクションを参照してください。

詳細は、APPLY_RECOMMENDATIONプロシージャを参照してください。

適格な表に対する推奨事項を生成し、推奨事項を手動で適用します。

1. AUTO_PARTITION_MODEパラメータをREPORT ONLYに設定して、自動パーティション化の推奨事項を作成して検証できるようにします。推奨は既存の表には適用されません。

   BEGIN
       DBMS_AUTO_PARTITION.CONFIGURE(
           PARAMETER_NAME  => 'AUTO_PARTITION_MODE', 
           PARAMETER_VALUE => 'REPORT ONLY');
   END;
   /

2. DBMS_AUTO_PARTITION APIを起動して、推奨表を生成します。

   -- DEFINE SQLPLUS BIND VARIABLE FOR RECOMMENDATION ID
   VARIABLE RECOMMENDATION_ID VARCHAR2(32);
   BEGIN
     :RECOMMENDATION_ID := DBMS_AUTO_PARTITION.RECOMMEND_PARTITION_METHOD();
   END;
   /

   推奨事項の分析および検証は、リソース集中型の長時間実行操作であり、かなりの時間がかかる場合があります。セカンダリ、非本番データベースでは、OracleはサービスHIGHを選択して十分なリソースを確認することをお薦めします。

3. DBA_AUTO_PARTITION_RECOMMENDATIONSビューを問い合せて、分析された表を確認します。

   SELECT TABLE_OWNER, TABLE_NAME, PARTITION_METHOD, PARTITION_KEY
       FROM DBA_AUTO_PARTITION_RECOMMENDATIONS
       WHERE RECOMMENDATION_ID = :RECOMMENDATION_ID
       ORDER BY RECOMMENDATION_SEQ;
   

4. この問合せを使用して、実行時に分析された特定の表(この例のTPCH.LINEITEM表)のレポートにドリルダウンします。

   SELECT REPORT
       FROM DBA_AUTO_PARTITION_RECOMMENDATIONS
       WHERE RECOMMENDATION_ID = :RECOMMENDATION_ID
           AND TABLE_OWNER = 'TPCH'
           AND TABLE_NAME  = 'LINEITEM';
   

5. APPLY_RECOMMENDATIONプロシージャを実行して、推奨事項を適用します。

   BEGIN
       DBMS_AUTO_PARTITION.APPLY_RECOMMENDATION(
            RECOMMENDATION_ID => :RECOMMENDATION_ID);
   END;
   /

   または、この例のTPCH.LINEITEM表を分析した特定の表の推奨事項を適用します。

   BEGIN
       DBMS_AUTO_PARTITION.APPLY_RECOMMENDATION(
           RECOMMENDATION_ID => :RECOMMENDATION_ID,
           TABLE_OWNER       => 'TPCH',
           TABLE_NAME        => 'LINEITEM');
   END;
   /

詳細は、CONFIGUREプロシージャを参照してください。

詳細は、RECOMMEND_PARTITION_METHODファンクションを参照してください。

詳細は、APPLY_RECOMMENDATIONプロシージャを参照してください。

適格な表に対する推奨事項の生成および自動適用

1. AUTO_PARTITION_MODEパラメータをREPORT ONLYに設定して、自動パーティション化の推奨事項を作成して検証できるようにします。推奨は既存の表には適用されません。

   BEGIN
       DBMS_AUTO_PARTITION.CONFIGURE(
           PARAMETER_NAME  => 'AUTO_PARTITION_MODE', 
           PARAMETER_VALUE => 'IMPLEMENT');
   END;
   /

2. DBMS_AUTO_PARTITION APIを起動して、推奨表を生成します。

   -- DEFINE SQLPLUS BIND VARIABLE FOR RECOMMENDATION ID
   VARIABLE RECOMMENDATION_ID VARCHAR2(32);
   BEGIN
     :RECOMMENDATION_ID := DBMS_AUTO_PARTITION.RECOMMEND_PARTITION_METHOD();
   END;
   /

   推奨事項の分析および検証は、リソース集中型の長時間実行操作であり、かなりの時間がかかる場合があります。セカンダリ、非本番データベースでは、OracleはサービスHIGHを選択して十分なリソースを確認することをお薦めします。

3. DBA_AUTO_PARTITION_RECOMMENDATIONSビューを問い合せて、分析された表を確認します。

   SELECT TABLE_OWNER, TABLE_NAME, PARTITION_METHOD, PARTITION_KEY
       FROM DBA_AUTO_PARTITION_RECOMMENDATIONS
       WHERE RECOMMENDATION_ID = :RECOMMENDATION_ID
       ORDER BY RECOMMENDATION_SEQ;
   

4. REPORT_LAST_ACTIVITYファンクションを使用して、前回の実行中に実行されたアクションに関するレポートを取得します。

   SELECT DBMS_AUTO_PARTITION.REPORT_LAST_ACTIVITY() FROM DUAL;
   

詳細は、CONFIGUREプロシージャを参照してください。

詳細は、RECOMMEND_PARTITION_METHODファンクションを参照してください。

詳細は、REPORT_LAST_ACTIVITYファンクションを参照してください。